setscreen ("text")
var WinID : int
WinID := Window.Open ("text")
var streamNumber : array 1 .. 100 of int    % assign 100 empty int var for the streamNumber
var fileName : array 1 .. 100 of string     % assign 100 empty string var for the fileName

% this does not mean that it can only delete 100 files
% since fileName (k) is replaced each time after file is deleted
% rather, the 100's here in these 2 arrays mean that you can delete
% 100 levels of folder in or lower than where this file is placed.

var k := 1      % initiate first streamNumber and fileName index

% please read from below the % line first

proc recursion
    Dir.Change (fileName (k))           % we now set that directory as our Dir.Current
    k += 1                              % we need to change both the streamNumber and the fileName var
    streamNumber (k) := Dir.Open (".")  % now we open the current directory
    assert streamNumber (k) > 0         % check for success
    for i : 1 .. 2
        fileName (k) := Dir.Get (streamNumber (k))      % the first 2 filenames will always be the current directory and the parent directory.
        exit when fileName (k) = ""                     % we cannot delete those yet
        put fileName (k)                               
    end for
    loop
        fileName (k) := Dir.Get (streamNumber (k))      % get the first file name from the new Dir.Current

        if fileName (k) = "" then           % if there are no more files then
            Dir.Close (streamNumber (k))    % close current directory
            put Dir.Current
            Dir.Delete (Dir.Current)        % delete current directory
            if Error.Last = eNoError then   % if success, proceed
                put " deleted"
            else                            % if not, print Error.LastMsg
                put " did not delete"
                put "Error: ", Error.LastMsg
            end if
            exit                            % exit
        end if                              % end if
       
        put fileName (k)
        File.Delete (fileName (k))          % delete the file
        if Error.Last = eNoError then       % if success, proceed
            put " deleted"
        else                                % if not, it means that it is yet another directory
            Dir.Delete (fileName (k))       % try deleting the directory
            if Error.Last = eNoError then   % if success, proceed
                put " deleted"
            else                            % if not, it means there are yet more files/folders in that directory
                recursion                   % repeat above steps
            end if
        end if
    end loop
    Dir.Change ("..")                       % if all files are deleted, change Dir.Current to the parent directory
    k -= 1                                  % change the streamNumber and the fileName var back to the parent folder
end recursion


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%


streamNumber (k) := Dir.Open (".")      % open current directory
assert streamNumber (k) > 0             % check for success
for i : 1 .. 2                         
    fileName (k) := Dir.Get (streamNumber (k))  % the first 2 filenames will always be the current directory and the parent directory.
    exit when fileName (k) = ""                 % we cannot delete those yet
    put fileName (k)
end for

loop
    fileName (k) := Dir.Get (streamNumber (k))  % get the first file name
    exit when fileName (k) = ""         % exit if there are no more files
    put fileName (k)
    File.Delete (fileName (k))          % delete the file
    if Error.Last = eNoError then       % if the file is deleted, then proceed to next filename
        put " deleted"
    else                                % if the file is not deleted, it means it is a directory
        Dir.Delete (fileName (k))       % attempt to delete the directory
        if Error.Last = eNoError then   % if the directory is deleted, then proceed to next filename
            put " deleted"
        else                            % if it is not, then it means there are files within that directory

            recursion                   % see Proc recursion

        end if
    end if
end loop