% Example.
setscreen ("graphics:400;300,offscreenonly,position:center;truemiddle")

var endGame := false
var x, y, b : int
const CX := maxx div 2
const CY := maxy div 2
const CR := 25

procedure shakeWindow (dx, dy : int)
    /* Parameters:
     dx - how far left and right the window can move.  Suggested:  1-5
     dy - how far up and down the window can move.  Suggested:  1-5
     dur - duration.  How long the window will shake for (in thousanths of a second.  Suggested:  200-800.
     */

    var tempX, tempY : int
    var xNot, yNot : int
    % Original positions, will be reassigned before termination.
    Window.GetPosition (Window.GetActive, tempX, tempY)
    Window.GetPosition (Window.GetActive, xNot, yNot)
    % Assign values.
    loop
        exit when endGame
        if tempX <= (xNot - dx) then
            for i : 1 .. dx
                tempX += 1
            end for
        elsif tempX >= (xNot + dx) then
            for i : 1 .. dx
                tempX -= 1
            end for
        else
            for i : 1 .. dx
                tempX += Rand.Int (-1, 1)
            end for
        end if

        if tempY <= (yNot - dy) then
            for i : 1 .. dy
                tempY += 1
            end for
        elsif tempY >= (yNot + dy) then
            for i : 1 .. dy
                tempY -= 1
            end for
        else
            for i : 1 .. dy
                tempY += Rand.Int (-1, 1)
            end for
        end if
        % Set bounds for x- and y-.  Stops shake from moving too far away.
        Window.SetPosition (Window.GetActive, tempX, tempY)
        %Delay
        delay (10)
        View.Update
    end loop
    Window.SetPosition (Window.GetActive, xNot, yNot)
end shakeWindow

process shakeProcess (dx, dy : int)
    shakeWindow (dx, dy)
end shakeProcess

process checkEnd
    var key : string (1)
    loop
        exit when endGame
        if hasch then
            getch (key)
            if ord (key) = 27 then
                endGame := true
                exit
            end if
        end if
    end loop
end checkEnd

process mouseCheck
    loop
        exit when endGame
        mousewhere (x, y, b)
    end loop
end mouseCheck

put "Ready? Press any key when ready!"
put "[Hint: position mouse right now]"
put "[ESC to quit]"

drawfilloval (CX, CY, CR, CR, 7)

View.Update

Input.Pause
cls

fork checkEnd
fork mouseCheck
fork shakeProcess (25, 25)

loop

    exit when endGame

    locate (maxrow - 1, 1)
    put "X: ", x ..
    locate (maxrow, 1)
    put "Y: ", y ..


    drawfilloval (CX, CY, CR, CR, 7)

    View.Update

    if sqrt (((x - CX) ** 2) + ((y - CY) ** 2)) > CR then
        endGame := true
        exit
    end if

end loop
if endGame then
    cls
    put "YOU LOSE"
end if