I don't think it can be done. the get command is not very flexible. You might try using a loop to getch several keystrokes to form your input string yourself.
| code: |
var key : string (1)
var input := ""
loop
getch (key)
exit when ord (key) = 10 %enter
input += key
locate (1, 1)
put input
end loop
|
This isn't error proofed though. If we want an integer for width:
| code: |
var key : string (1)
var input := ""
var width : int
loop
getch (key)
exit when ord (key) = 10 %enter
if strintok (input + key) then
input += key
end if
locate (1, 1)
put input
end loop
if strintok (input) then
width := strint (input)
else
width := -1 %error! no value.
end if
put width
|
Then it might be useful to make this into a procedure.
| code: |
var width : int
proc getInteger (var variable : int, outputRow, outputCol : int)
var key : string (1)
var input := ""
loop
getch (key)
exit when ord (key) = 10 %enter
if strintok (input + key) then
input += key
end if
locate (outputRow, outputCol)
put input
end loop
if strintok (input) then
variable := strint (input)
end if
end getInteger
getInteger (width, 10, 10)
|
You can also do things like deleting characters:
| code: |
var width : int
proc getInteger (var variable : int, outputRow, outputCol : int)
var key : string (1)
var input := ""
loop
getch (key)
exit when ord (key) = 10 %enter
if ord (key) = 8 and input ~= "" then %backspace
input := input (1 .. * -1)
elsif strintok (input + key) then
input += key
end if
locate (outputRow, outputCol)
put input
end loop
if strintok (input) then
variable := strint (input)
end if
end getInteger
getInteger (width, 10, 10)
|
You could take this even further too, and make yourself your very own text box. I made a text box class that is almost completely functional without too much trouble. |
...
