var forest := Pic.FileNew ("forest.jpg")
var grass := Pic.FileNew ("grass layer.bmp")
var chars : array char of boolean
var startTime : int
var lastFrameTime : int := 0
var frameTime : int := 0
var lastFrameRate : int := 0
var font1 := Font.New ("Times New Roman:16")
const MAX_FRAME_RATE : int := 30
const MIN_MILLISECS_BETWEEN_FRAMES : int := 1000 div MAX_FRAME_RATE
var backgroundPictureWidth1, backgroundPictureWidth2 : int
var backgroundPictureX1, backgroundPictureX2 : int

procedure DrawScreen
    var frameRate : int

    Pic.Draw (forest, -backgroundPictureX1, 0, picCopy)

    frameRate := 1000 div (Time.Elapsed - frameTime)
    if abs (lastFrameRate - frameRate) > 1 then
        lastFrameRate := frameRate
    end if
    Font.Draw (intstr (lastFrameRate), 0, 370, font1, white)
    frameTime := Time.Elapsed

    Pic.Draw (grass, -backgroundPictureX2, 0, picMerge)

    View.Update
end DrawScreen

backgroundPictureWidth1 := Pic.Width (forest)
backgroundPictureWidth2 := Pic.Width (grass)
backgroundPictureX1 := (backgroundPictureWidth1 - (maxx + 1)) div 2
backgroundPictureX2 := (backgroundPictureWidth2 - (maxx + 1)) div 2

startTime := Time.Elapsed

loop
    Input.KeyDown (chars)
    if chars (KEY_LEFT_ARROW) then
        backgroundPictureX1 += 5
        backgroundPictureX2 += 10
    end if
    if chars (KEY_RIGHT_ARROW) then
        backgroundPictureX1 -= 5
        backgroundPictureX2 -= 10
    end if
    DrawScreen

    if Time.Elapsed - lastFrameTime < MIN_MILLISECS_BETWEEN_FRAMES then
        delay (MIN_MILLISECS_BETWEEN_FRAMES - (Time.Elapsed - lastFrameTime))
    end if
    lastFrameTime := Time.Elapsed
end loop