%THE GAME OF LIFE%

const maxX := 50    %maxx
const maxY := 50    %maxy
const res := 5      %how big the cells are
const density := 4  %the odds a particular cell will be occupied at the start of the proggy
const border := 10  %the amount of empty cells surrounding the border
const fps := 10   %the amount of frames per second

var t : int

var life : array 0 .. maxX + 1, 0 .. maxY + 1 of int
var temp : array 0 .. maxX + 1, 0 .. maxY + 1 of int

proc loadRandom (d, c : int)
    for x : 0 .. maxX + 1
        for y : 0 .. maxY + 1
            if x > c and x < maxX - c and y > c and y < maxY - c then
                if x = 0 or y = 0 or x = maxX + 1 or y = maxY + 1 then
                    life (x, y) := 0
                elsif Rand.Int (0, d) = 0 then
                    life (x, y) := 1
                else
                    life (x, y) := 0
                end if
            else
                life (x, y) := 0
            end if
            temp (x, y) := life (x, y)
        end for
    end for
end loadRandom

fcn howMany (x : int, y : int) : int
    result temp (x - 1, y + 1) + temp (x, y + 1) + temp (x + 1, y + 1) + temp (x - 1, y) + temp (x + 1, y) + temp (x - 1, y - 1) + temp (x, y - 1) + temp (x + 1, y - 1)
end howMany

proc FPS (fps : int)
    if Time.Elapsed - t < 1000 / fps then
        delay (round ((1000 / fps) - (Time.Elapsed - t)))
    end if
end FPS

loadRandom (density, border)

setscreen ("graphics:" + intstr (maxX * res + 50) + ";" + intstr (maxY * res + 50) + ", offscreenonly, nobuttonbar")
loop
    t := Time.Elapsed
    for x : 1 .. maxX
        for y : 1 .. maxY
            temp (x, y) := life (x, y)
            drawfillbox (x * res + 25 - res, y * res + 25 - res, x * res + 25, y * res + 25, life (x, y))
        end for
    end for
    for x : 1 .. maxX
        for y : 1 .. maxY
            if life (x, y) = 1 then
                if howMany (x, y) <= 1 or howMany (x, y) >= 4 then
                    life (x, y) := 0
                end if
            else
                if howMany (x, y) = 3 then
                    life (x, y) := 1
                end if
            end if
        end for
    end for
    drawbox (25, 25, maxX * res + 25, maxY * res + 25, 7)
    View.Update
    FPS (fps)
end loop