%File "turtlefat.tu"
%A class for creating a turtle that can draw
%with different widths of lines
unit
class TurtleFatCl

    inherit TurtleCl in "turtlecl.tu"
    export SetWidth

    proc ball (xc, yc, radius, clr : int)
        Draw.FillOval (xc, yc, radius,radius,  clr)
    end ball
    var width : int := 1
    proc SetWidth (newWidth : int)
        width := newWidth
    end SetWidth
    proc drawFatLine (x1, y1, x2, y2, clr, width : int)
        const len : real := sqrt ( (x2 - x1) ** 2 + (y2 - y1) ** 2)
        const sinTheta : real := (y2 - y1) / len
        const cosTheta : real := (x2 - x1) / len
        const radius := width div 2 + 1
        const dx : real := radius * cosTheta / 2
        const dy : real := radius * sinTheta / 2

        var xpos : real := x1
        var ypos : real := y1

        loop
            ball (round (xpos), round (ypos), radius, clr)
            xpos += dx
            ypos += dy
            exit when sqrt ( (x2 - xpos) ** 2 + (y2 - ypos) ** 2) < (radius
                / 2)
        end loop
    end drawFatLine

    body procedure Move (distance : int)
        const newx := round (x + cosd (angle) * distance)
        const newy := round (y + sind (angle) * distance)
        if showing then
            if width = 1 then
                Draw.Line (x, y, newx, newy, clr)
            else
                drawFatLine (x, y, newx, newy, clr, width)
            end if
        end if
        x := newx
        y := newy
    end Move
end TurtleFatCl