setscreen ("offscreenonly")

%declare constants
const paddleH := 80
const paddleW := 10
const x := 1
const y := 2
const paddleClr := 7
const ballClr := 7
const ballR := 10
const paddleSpd := 4
const ballInitSpd := 2
const ballAccel := 1.01

%declare variables
var paddle : array 1 .. 2, 1 .. 2 of int
paddle (1, x) := 50
paddle (1, y) := maxy div 2
paddle (2, x) := maxx - 50
paddle (2, y) := maxy div 2
var paddleDir : array 1 .. 2 of int := init (0, 0)

var ballSpd : array 1 .. 2 of real := init (ballInitSpd, ballInitSpd)
var ballCoords : array 1 .. 2 of real
ballCoords (x) := maxx div 2
ballCoords (y) := maxy div 2

var score : array 1 .. 2 of int := init (0, 0)

var keys : array char of boolean

%moves the paddle as long as it will end up within the screen
procedure movePaddle (pNum, direction : int)
    if paddle (pNum, y) + direction > paddleH div 2 and paddle (pNum, y) + direction < maxy - paddleH div 2 then
        paddle (pNum, y) += direction
    end if
    drawfillbox (paddle (pNum, x) - paddleW div 2, paddle (pNum, y) - paddleH div 2, paddle (pNum, x) + paddleW div 2, paddle (pNum, y) + paddleH div 2, paddleClr)
end movePaddle

%checks whether the ball hits one of the paddles
%if it does, the balls direction is reversed
procedure ballHitsPaddle
    if ballCoords (y) > paddle (1, y) - paddleH div 2 and ballCoords (y) < paddle (1, y) + paddleH div 2 then
        if ballCoords (x) > (paddle (1, x) - paddleW div 2) + ballR and ballCoords (x) < (paddle (1, x) + paddleW div 2) + ballR then
            ballSpd (x) *= -1
            ballCoords (x) := paddle (1, x) + ballR + paddleW
        end if
    end if
    if ballCoords (y) > paddle (2, y) - paddleH div 2 and ballCoords (y) < paddle (2, y) + paddleH div 2 then
        if ballCoords (x) > (paddle (2, x) - paddleW div 2) - ballR and ballCoords (x) < (paddle (2, x) + paddleW div 2) - ballR then
            ballSpd (x) *= -1
            ballCoords (x) := paddle (2, x) - ballR - paddleW
        end if
    end if
end ballHitsPaddle

%moves the ball
%if it hits the top/bottom wall, the speed is increased
%if the ball hits the left/right wall, the balls x,y and direction variables are reset and the
%appropriate score is incremented
procedure moveBall
    ballCoords (x) += ballSpd (x)
    ballCoords (y) += ballSpd (y)
    if ballCoords (x) < ballR then
        ballCoords (x) := maxx div 2
        score (2) += 1
        ballSpd (1) := ballInitSpd
        ballSpd (2) := ballInitSpd
    elsif ballCoords (x) > maxx - ballR then
        ballCoords (x) := maxx div 2
        score (1) += 1
        ballSpd (1) := ballInitSpd
        ballSpd (2) := ballInitSpd
    end if
    if ballCoords (y) < ballR or ballCoords (y) > maxy - ballR then
        ballSpd (y) *= -ballAccel
        ballSpd (x) *= ballAccel
    end if
    drawfilloval (round (ballCoords (x)), round (ballCoords (y)), ballR, ballR, ballClr)
end moveBall

%checks which keys are pressed
%changes the appropriate paddle direction if a key is pressed
procedure getKeys
    Input.KeyDown (keys)
    if keys (KEY_UP_ARROW) then
        paddleDir (2) := paddleSpd
    elsif keys (KEY_DOWN_ARROW) then
        paddleDir (2) := -paddleSpd
    else
        paddleDir (2) := 0
    end if
    if keys (KEY_SHIFT) then
        paddleDir (1) := paddleSpd
    elsif keys (KEY_CTRL) then
        paddleDir (1) := -paddleSpd
    else
        paddleDir (1) := 0
    end if
end getKeys

%main loop which displays the score and calls all the procedures
loop
    locate (1, 5)
    put "Player 1: ", score (1)
    locate (1, 47)
    put "Player 2 : ", score (2)
    drawline (maxx div 2, maxy, maxx div 2, 0, 7)
    getKeys
    ballHitsPaddle
    movePaddle (1, paddleDir (1))
    movePaddle (2, paddleDir (2))
    moveBall
    View.Update
    delay (10)
    cls
end loop