module MyMouse

    import Mouse, Math

    export Calibrate, X, Y

    var calibrated : boolean := false
    % Calibrated x and y coordinates for the mouse
    var MouseCalibratedX, MouseCalibratedY : int
   
    % Return the calibrated x coordinate of the mouse
    fcn X (mouseX : int) : int
        if not calibrated then % Error if not yet calibrated
            Error.Halt ("Mouse has not yet been calibrated.")
        end if
        result mouseX - MouseCalibratedX
    end X
   
    % Return the calibrated x coordinate of the mouse
    fcn Y (mouseY : int) : int
        if not calibrated then % Error if not yet calibrated
            Error.Halt ("Mouse has not yet been calibrated.")
        end if
        result mouseY - MouseCalibratedY
    end Y

    % Create a new location to be 0,0 for mouse coordinates
    proc Calibrate (winID : int)
   
        % Declare Strings (for easy modification)
        const MouseString1 := "Mouse Area: This window represents the area to which the mouse will be calibrated."
        const MouseString2 := "Place windows in desired position and click on center of target."

        % Put the current selected and active window in memory
        var SelectedWindow, ActiveWindow : int
        SelectedWindow := Window.GetSelect
        ActiveWindow := Window.GetActive

        Window.Select (winID) % Select the window we are calibrating for so we can get its size with maxx and maxy

        % Prepare a second window
        var win2ID, win2Width, win2Height : int
        win2Width := maxx
        win2Height := maxy
        win2ID := Window.Open ("graphics:" + intstr (win2Width) + ";" + intstr (win2Height) + ",offscreenonly,position:0;0")

        % Print text if the window is big enough (unless your window is really small there should be no problem)
        if (win2Width - Font.Width (MouseString1, defFontID)) > 0 and
                (win2Width - Font.Width (MouseString2, defFontID)) > 0 and
                win2Height > 100 then
            locatexy ((win2Width - Font.Width (MouseString1, defFontID)) div 2, win2Height - 100)
            put MouseString1
            locatexy ((win2Width - Font.Width (MouseString2, defFontID)) div 2, win2Height - 120)
            put MouseString2
        end if

        % Draw "Target" for calibration
        Draw.FillOval (win2Width div 2, win2Height div 2, 30, 30, 12)
        Draw.Line (win2Width div 2, win2Height div 2 - 10, win2Width div 2, win2Height div 2 + 10, 1)
        Draw.Line (win2Width div 2 - 10, win2Height div 2, win2Width div 2 + 10, win2Height div 2, 1)

        View.Update % Update Window

        % Declare some variables for Mouse.ButtonWait
        var mX_, mY_, mBn_, mB_ : int
        loop
            Mouse.ButtonWait ("down", mX_, mY_, mBn_, mB_)
            Window.Select (win2ID)
            exit when Math.Distance (mX_, mY_, win2Width div 2, win2Height div 2) < 5 % Check if the user is within 5 pixels of the center of the target
            View.Update
        end loop
       
        % Close calibration window and set windows back to the way they were
        Window.Close (win2ID)
        Window.SetActive (ActiveWindow)
        Window.Select (SelectedWindow)

        % Set the coordinates that will now be the mouse's 0,0 position
        Mouse.Where (mX_,mY_,mB_)
        MouseCalibratedX := mX_ - (win2Width div 2)
        MouseCalibratedY := mY_ - (win2Height div 2)

        calibrated := true

    end Calibrate

end MyMouse

% Now let's create a simple game! (I saw this used as an example for collision detection somwhere on the forum)


var PlayerX, PlayerY, EnemyX, EnemyY : int % Player and Enemy circle
const PlayerRad := 15 % Player Radius
const EnemyRad := 25 % Enemy Radius

var mX, mY, mB : int % Mouse variables

% Simple collision detection function
fcn Collision : boolean
    result Math.Distance (PlayerX, PlayerY, EnemyX, EnemyY) < PlayerRad + EnemyRad
end Collision

% I'm going to make the game window half the screen's size...  almost (the borders on the windows and the taskbar screw it up)
const HalfScrnWdth := (Config.Display (cdScreenWidth) + 1) div 2     % Half the screen's width
const HalfScrnHght := (Config.Display (cdScreenHeight) + 1) div 2     % Half the screen's height

View.Set ("graphics:" + intstr (HalfScrnWdth) + ";" + intstr (HalfScrnHght) + ",offscreenonly,nobuttonbar,position:" + intstr (HalfScrnWdth) + ";" + intstr (HalfScrnHght))

% Set initial player position at center
PlayerX := maxx div 2
PlayerY := maxy div 2

% Calibrate mouse
MyMouse.Calibrate(defWinId) % defWinId is the default window ID

loop
    % Create a new enemy
    loop
        EnemyX := Rand.Int (0, maxx)
        EnemyY := Rand.Int (0, maxy)
        exit when not Collision
    end loop

    loop
        % Move player circle to the calibrated x and y coordinates
        Mouse.Where (mX, mY, mB)
        PlayerX := MyMouse.X (mX)
        PlayerY := MyMouse.Y (mY)

        % Place player at edge of screen if mouse is outside the calibrated area
        if PlayerX < PlayerRad then
            PlayerX := PlayerRad
        elsif PlayerX > maxx - PlayerRad then
            PlayerX := maxx - PlayerRad
        end if
        if PlayerY < PlayerRad then
            PlayerY := PlayerRad
        elsif PlayerY > maxy - PlayerRad then
            PlayerY := maxy - PlayerRad
        end if

        % Draw player and enemy
        cls
        put "Press any key to recalibrate the mouse"
        Draw.FillOval (PlayerX, PlayerY, PlayerRad, PlayerRad, 12)
        Draw.FillOval (EnemyX, EnemyY, EnemyRad, EnemyRad, 1)
        View.Update
       
        % If a key is pressed, recalibrate the mouse
        if hasch then
        MyMouse.Calibrate(defWinId)
        Input.Flush % Empty the key buffer
        end if
       
        exit when Collision % Create a new enemy on collision
       
        Time.DelaySinceLast (1000 div 60)
    end loop
end loop

put "Hi!"

put "OMG"
include "MyExtraFile.t"

put "OMG"
put "Hi!"