View.Set ("graphics,offscreenonly")

var segX : array 1 .. 1000 of int % x-position of segments
var segY : array 1 .. 1000 of int % y-position of segments

var foodX : int  % x-position of the food
foodX := Rand.Int (30, 300)
var foodY : int % y-position of the food
foodY := Rand.Int (100, 300)

%BONUS FOOD
var bonusFoodX : int
bonusFoodX := Rand.Int (30, 300)
var bonusFoodY : int
bonusFoodY := Rand.Int (30, 300)

var numSegs : int % number of segments on the snake

% 1 - up, 2 - right, 3 - down, 4 - left
var direction : int
direction := 2


var keys : array char of boolean


Input.KeyDown (keys)
numSegs := 3 % starting number of segments

% STARTING POSITION OF THE 3 SEGMENTS
segX (1) := 200
segY (1) := 100
segX (2) := 180
segY (2) := 100
segX (3) := 180
segY (3) := 80

loop
    Input.KeyDown (keys) % update keyboard info

    % DRAWING THE BODY
    for i : 2 .. numSegs
        Draw.FillOval (segX (i), segY (i), 10, 10, black)
    end for

    %DRAWING THE HEAD
    Draw.FillOval (segX (1), segY (1), 10, 10, 13)

    % DRAWING THE FOOD
    Draw.FillOval (foodX, foodY, 12, 12, brightred)
    Draw.FillOval (bonusFoodX, bonusFoodY, 12, 12, blue)

    % user input
    if keys (KEY_UP_ARROW) = true then % moving the snake up
        direction := 1
    elsif keys (KEY_RIGHT_ARROW) = true then % moving the snake right
        direction := 2
    elsif keys (KEY_DOWN_ARROW) = true then % movng the snake down
        direction := 3
    elsif keys (KEY_LEFT_ARROW) = true then % moving the snake left
        direction := 4
    end if

    % To do : CHECK IF IT HIT THE WALLS
    if segX (1) >= maxx then
        segX (1) := -7

    elsif segX (1) <= -7 then
        segX (1) := maxx - 7
    end if

    if segY (1) >= maxy then
        segY (1) := -7

    elsif segY (1) <= -7 then
        segY (1) := maxy - 7
    end if

    % check if food is eaten and move the food
    if whatdotcolour (segX (1), segY (1)) = brightred then % TODO: actually check real food
        numSegs := numSegs + 1 % adding a segment when food is eaten
        foodX := Rand.Int (30, 400) % moving the food
        foodY := Rand.Int (60, 300) % moving the food
    end if
    %check if hit bonus food
    if whatdotcolour (segX (1), segY (1)) = blue then
        numSegs := numSegs + 3
        bonusFoodX := Rand.Int (30, 400) % moving the food
        bonusFoodY := Rand.Int (60, 300) % moving the food
    end if
   
    % MOVEMENT
    % Move Body
    for decreasing i : numSegs .. 2
        segX (i) := segX (i - 1)
        segY (i) := segY (i - 1)
    end for

    % Move Head
    if direction = 1 then     % up
        segY (1) := segY (1) + 20
    elsif direction = 2 then     % right
        segX (1) := segX (1) + 20
    elsif direction = 3 then     % down
        segY (1) := segY (1) - 20
    elsif direction = 4 then     % left
        segX (1) := segX (1) - 20
    end if

    % TODO: check if hit self
    if whatdotcolour (segX (1), segY (1)) = black then
        numSegs := 3
        delay (200)
    end if

    View.Update ()
    delay (100)
    cls ()
end loop