View.Set ("text")                                   % Start in text mode
var defMusDir : string                              % Root music directory
var searchExt := ".mp3"                             % Look for MP3's
const lengthExt := (length (searchExt) - 1)         % Length of extension
var mp3Counter : int := 0                           % Count number of MP3's
var songFullPath : flexible array 1 .. 0 of string  % Obtain full path of MP3

procedure ScanDir (dir : string, switch : string)   % Scan directory for files
    var streamNumber : int                          % File stream
    var fileName : string                           % Hold file name
    streamNumber := Dir.Open (dir)                  % Open directory for output
    assert streamNumber > 0                         % Make sure stream is ready

    loop                                            % Main loop
        fileName := Dir.Get (streamNumber)          % Obtain filename from directory stream
        exit when fileName = "" or hasch            % Quit program when user presses a key or end of stream

        if (fileName not= ".") and (fileName not= "..") and length (fileName) > 4 then              % Makes sure we don't leave root and file is big enough for parsing
            if fileName (length (fileName) - 3 .. length (fileName)) = searchExt then               % Check if file is an MP3
                mp3Counter += 1                                                                     % Found an mp3!
                new songFullPath, mp3Counter                                                        % Resize array dynamically
                songFullPath (mp3Counter) := dir + fileName                                         % Save path + filename to array
            end if

            if Dir.Exists (dir + fileName) then                                                     % If a directory is found
                ScanDir (dir + fileName + "/", "calculate")                                         % Recursively look for more MP3s & directories within that folder
            end if

        end if
    end loop
    Dir.Close (streamNumber)                        % Close the stream
end ScanDir

put "Please enter a music directory: " ..           % Display message to user
get defMusDir : *                                   % User inputs directory to scan
if defMusDir (length (defMusDir)) not= "/" then     % Checks if user ended with a forward slash
    defMusDir += "/"                                % Appends forward slash to prevent error
end if
ScanDir (defMusDir, "calculate")                    % Calculate number of MP3's
const numOfMP3 := mp3Counter                        % Store number of MP3's
ScanDir (defMusDir, "store")                        % Store all MP3's
   
var randomSong := songFullPath (Rand.Int (1, numOfMP3)) % Selects a random song
put "Playing ", randomSong                              % Display name of song selected
Music.PlayFileReturn (randomSong)                       % Plays that song