% Since counting the framerate is considered logic, and blitting/rendering
% the scene also takes (rather alot) of time, standard practice would be to have the
% framerate calculation (Time.Elapsed - lastT) to include the render section.
% You would then have the logic of the current frame react to the framerate of the
% last frame.

View.Set ("graphics,offscreenonly,nobuttonbar")
var lastT, codeTook, frame, codeFPS, controledFPS, howMuchDelay, renderingTime : int := 0
var targetFPS := 60
var n : int := 50000 % 1000 to test fast, 1000000 to test slow
var angle : real
loop

    % --- Logic ---
    lastT := Time.Elapsed

    % Count to n
    for i : 1 .. n
    end for



    frame += 1
    codeTook := Time.Elapsed - lastT
    if codeTook = 0 then
        codeFPS := maxint
    else
        codeFPS := 1000 div codeTook
    end if
    howMuchDelay := (1000 div targetFPS) - codeTook



    if howMuchDelay > 0 then
        % Code is running too fast!
        % Using a delay based on how fast your code ran will
        % make sure each frame will be as close to the same
        % time taken as possible.
        % Try: n = 1000
       
        % 1 second divided by how many frames your target is,
        % then substract the time already spent processing code
        Time.Delay (howMuchDelay)
    end if

    codeTook := Time.Elapsed - lastT
    controledFPS := 1000 div codeTook

    % Having movement based on time will let any slow machines
    % play in real time but suffer major frame skips.
    % Try: n = 1000000
    renderingTime := Time.Elapsed
    angle := renderingTime / 10

    % --- Render ---
    cls
    Draw.FillOval (round (maxx div 2 + cosd (angle) * 80), round (maxy div 2 + sind (angle) * 80), 10, 10, red)


    put "Frame: ", frame
    put "    Counting to: ", n
    put "    Code Took: ", codeTook, " ms"
    put "    Code FPS: ", codeFPS
    put "    Delay: ", howMuchDelay
    put "    Controled FPS: ", controledFPS, " (Target = ", targetFPS, ")"

    View.Update

    % Adjust number to count to based on how fast the code took to run
    % Not really neccessary for FPS control but makes the demo more
    % dynamic and finds the target for the current system (benchmark?)
    if codeFPS > controledFPS then
        n += 1000
    elsif codeFPS = 0 then

    else
        n -= 1000
    end if

end loop