%Platformer

%Imports Classes
%import TitlePageCl in "titlePage.t", DeadPageCl in "deadpage.t", WinPageCl in "winpage.t"


% Creates a window
var winID : int := Window.Open ("graphics: 595;400, offscreenonly,nobuttonbar, title: Square?")

/*Creates variables for classes
 var TitlePage1 : ^TitlePageCl
 new TitlePage1

 var DeadPage1 : ^DeadPageCl
 new DeadPage1

 var WinPage1 : ^WinPageCl
 new WinPage1*/

% Type used for points and vectors to track
type Vector :
    record
        x : real
        y : real
    end record

% Picture(s) used for background and collision detection
var platform1 : int := Pic.FileNew ("platform1.bmp")
var platform2 : int := Pic.FileNew ("platform2.bmp")

% Holds keyboard data
var chars : array char of boolean
var pressedChars : array char of boolean
Input.KeyDown (chars)
pressedChars := chars

% Position and velocity of the player
var pos : Vector
pos.x := 150;
pos.y := 175
var vel : Vector
vel.x := 0;
vel.y := 0

% Position of the camera
var cam : Vector
cam.x := 0;
cam.y := 0

% Size of the player
var size : Vector
size.x := 15;
size.y := 15

% Collision booleans and directions
var isTouchingGround : boolean := false
var isTouchingWall : boolean := false
var wallDir : int := 0

%Score
var scoreSeconds : int := 0

%Pause Key Variable
var PauseKey : char

%Font Varialbes
var font1 : int := Font.New ("Fixedsys:30")
var font2 : int := Font.New ("Fixedsys:12")

%Variables for level changing
var level1b : boolean := true
var level2b : boolean := false


%Console Window and Settings(code)


var console : int := Pic.FileNew ("console.jpg")
var consoleText : string
var x, y, mouse : int
var consoleTextFont : int := Font.New ("Arial:9")
var realCommand : boolean := false

proc consoleWindow
    var winID2 : int := Window.Open ("graphics: 370;340,nobuttonbar, title: Console")

    loop
        Mouse.Where (x, y, mouse)
        Pic.Draw (console, 0, 0, picCopy)
        locate (20, 4)
        colorback (26)
        get consoleText
        exit
    end loop

    if consoleText = "teleport1" then
        realCommand := true
    end if

    if consoleText = "teleport2" then
        realCommand := true
    end if

    if consoleText = "homepos" then
        realCommand := true
    end if

    if consoleText = "shrink" then
        realCommand := true
    end if

    loop
        if realCommand = true then
            Font.Draw ("Console: User has implemented the following: ", 25, maxy - 55, consoleTextFont, white)
            Font.Draw (consoleText, 25, maxy - 70, consoleTextFont, white)
            delay (2500)
            exit
        else
            Font.Draw ("Invalid Command Line", 25, maxy - 55, consoleTextFont, white)
            delay (2500)
            exit
        end if
    end loop

    loop
        Font.Draw ("You can only apply one command at a time.", 25, maxy - 170, consoleTextFont, white)
        delay (2500)
        Window.Hide (winID2)
        exit
    end loop


end consoleWindow

% Faster to draw alot of fillboxes
proc fillbox (x : real, y : real, x2 : real, y2 : real, c : int)
    Draw.FillBox (round (x + cam.x), round (y + cam.y), round (x2 + cam.x), round (y2 + cam.y), c)
end fillbox

proc deadScreen
    cls
    put "dead"
end deadScreen

proc levelChange
    % Draws background
    if level1b = true then
        Pic.Draw (platform1, round (cam.x), round (cam.y), picCopy)
    elsif level2b = true then
        pos.x := 150;
        pos.y := 175
        cls
        Pic.Draw (platform2, round (cam.x), round (cam.y), picCopy)
    end if
end levelChange

proc level
    loop
        %Updates Score
        scoreSeconds := scoreSeconds + 1

        %Fills non-picture areas with a distracting colour
        drawfill (-100, -100, green, black)

        % Get keyboard state
        Input.KeyDown (chars)

        %Pause button
        if chars (' ') then
            Font.Draw ("Game Paused", maxx div 2, maxy - 50, font1, red)
            Font.Draw ("Press any key to continue", maxx div 2, maxy - 100, font2, 11)
            Draw.FillStar (150, 285, 300, 400, yellow)
            View.Update
            PauseKey := getchar
        end if

        %Cheats button
        if chars ('c') then
            /*cls
             put scoreSeconds
             delay (1000)*/
            consoleWindow
        end if

        %Restart button
        if chars ('r') then
            pos.x := 150;
            pos.y := 275
        end if


        % Move dependent of collision with level and what keys are down
        if (isTouchingGround) then
            if chars ('w') then
                vel.y += 15
            end if

            if chars ('a') then
                vel.x -= 1
            end if
            if chars ('d') then
                vel.x += 1
            end if
        else
            % Wall Jump
            if (isTouchingWall) then
                if chars ('w') then
                    vel.y += 15
                    vel.x += 5 * wallDir
                end if
            end if

            if chars ('a') then
                vel.x -= 0.1
            end if
            if chars ('d') then
                vel.x += 0.1
            end if
        end if

        % isTouchingGround is by default false and also helps with jump
        isTouchingGround := false

        % If moving left
        if (round (vel.x) < 0) then
            if (whatdotcolour (round (pos.x + vel.x - size.x + cam.x), round (pos.y - size.y + cam.y)) = black or whatdotcolour (round (pos.x + vel.x - size.x + cam.x), round (pos.y + size.y +
                    cam.y)) =
                    black) then


                isTouchingWall := true
                wallDir := 1

                vel.x := 0
            else
                pos.x += vel.x
                isTouchingWall := false
            end if

            % If moving right
        elsif (round (vel.x) > 0) then
            % Does the player hit a wall?
            if (whatdotcolour (round (pos.x + vel.x + size.x + cam.x), round (pos.y - size.y + cam.y)) = black or whatdotcolour (round (pos.x + vel.x + size.x + cam.x), round (pos.y + size.y +
                    cam.y)) =
                    black) then
                % Find where the player hit the wall
                isTouchingWall := true
                wallDir := -1

                vel.x := 0
            else
                pos.x += vel.x
                isTouchingWall := false
            end if
        end if

        %If Dead
        if pos.y - size.y < -50 then
            %DeadPage1 -> deadPage
        end if


        % If moving down
        if (vel.y < 0) then
            % Does the player hit a floor?
            if (whatdotcolour (round (pos.x - size.x + cam.x), round (pos.y + vel.y - size.y + cam.y)) = black or whatdotcolour (round (pos.x + size.x + cam.x), round (pos.y + vel.y - size.y +
                    cam.y)) =
                    black) then
                % Find where the player hit the floor
                for i : round (vel.y) .. 0
                    if (whatdotcolour (round (pos.x - size.x + cam.x), round (pos.y + i - size.y + cam.y)) ~= black and whatdotcolour (round (pos.x + size.x + cam.x), round (pos.y + i -
                            size.y +
                            cam.y))
                            ~= black) then
                        % Move the player there
                        pos.y := round (pos.y) + i;
                    end if
                end for

                isTouchingGround := true

                vel.y := 0
            else
                pos.y += vel.y
            end if
            % If moving up
        elsif (vel.y > 0) then
            % Does the player hit a ceiling?
            if (whatdotcolour (round (pos.x - size.x + cam.x), round (pos.y + vel.y + size.y + cam.y)) = black or whatdotcolour (round (pos.x + size.x + cam.x), round (pos.y + vel.y + size.y +
                    cam.y)) =
                    black) then
                % Find where the player hit the ceiling
                for decreasing i : round (vel.y) .. 0
                    if (whatdotcolour (round (pos.x - size.x + cam.x), round (pos.y + i + size.y + cam.y)) ~= black and whatdotcolour (round (pos.x + size.x + cam.x), round (pos.y + i +
                            size.y +
                            cam.y))
                            ~= black) then
                        % Move the player there
                        pos.y := round (pos.y) + i;
                    end if
                end for
                vel.y := 0
            else
                pos.y += vel.y
            end if
        end if

        % Move camera to center it on the player
        cam.x -= round ((pos.x + cam.x - maxx / 2) / 10)
        cam.y -= round ((pos.y + cam.y - maxy / 2) / 10)

        % Move downward to simulate gravity, less when against a wall
        if (isTouchingWall and vel.y < 0) then
            vel.y -= 9.8 / 30
        else
            vel.y -= 9.8 / 10
        end if

        % Set a maximum speed, less against a wall
        if (isTouchingWall) and (vel.y < -10) then
            vel.y := -10
        end if

        if (vel.y < -15) then
            vel.y := -15
        elsif (vel.y > 15) then
            vel.y := 15
        end if

        if (vel.x < -15) then
            vel.x := -15
        elsif (vel.x > 15) then
            vel.x := 15
        end if

        % Simulates friction
        if (isTouchingGround) then
            vel.x /= 1.2
        end if

        % Sets previous key states to the current key states
        pressedChars := chars

        % Clears
        cls

        levelChange

        % Draws player
        fillbox (pos.x - size.x, pos.y - size.y, pos.x + size.x, pos.y + size.y, blue)

        % Updates window
        Window.Update (winID)

        % Delays
        delay (7)
    end loop
end level

var backgroundTitle : int := Pic.FileNew ("title.jpg")
var backgroundInstruction : int := Pic.FileNew ("instructions.jpg")
var backgroundPassword : int := Pic.FileNew ("password.jpg")
var password1 : string


proc instruction
    loop
        Input.KeyDown (chars)
        cls
        Pic.Draw (backgroundInstruction, 0, 0, picCopy)
        if chars (KEY_ENTER) then
            cls
            level
        end if
        View.Update
    end loop
end instruction


proc password
    loop
        View.Set ("offscreenonly")
        cls
        Pic.Draw (backgroundPassword, 0, 0, picCopy)
        locate (13, 12)
        View.Update
        get password1
        if password1 = "awesome" then
            cls
            level
        end if
    end loop
end password



proc titlePage

    %Starts Playing Music
    Music.PlayFileLoop ("Music.mp3")


    loop
        View.Set ("offscreenonly")
        Mouse.Where (x, y, mouse)
        Pic.Draw (backgroundTitle, 0, 0, picCopy)
        if x > 100 and x < 250 and y > 200 and y < 230 and mouse = 1 then
            level
        end if

        if x > 100 and x < 550 and y > 140 and y < 180 and mouse = 1 then
            instruction
            View.Update

        end if

        if x > 100 and x < 500 and y > 80 and y < 120 and mouse = 1 then
            password
            View.Update
            exit
        end if
        View.Update
    end loop

end titlePage


titlePage