proc DrawNSidedShape (x, y, n, r, rot : int) %x and y position, number of sides, radius, rotation
    var disx, disy : real %the distance from the center to the current point
    var angle : real %the angle around the circle
    var pointsx : array 1 .. n of int %arrays to store the points
    var pointsy : array 1 .. n of int
    for i : 1 .. n %%for every side
        angle := 360 / n * (i - 1) + 90 + rot %the angle is 360/number of sides*what side it is
        %I subtract one so it starts at 0, add the rotation and 90
        %which just centers it at the top
        disx := cosd (angle) * r %calculate the distance in x cosine of angle * radius
        disy := sind (angle) * r %same as above except with y and sine
        pointsx (i) := x + round (disx) %add this to the list of points
        pointsy (i) := y + round (disy)
    end for
    for i : 1 .. n - 1 %for every point except the last
        %draw a point connecting it to the nect one
        drawline (pointsx (i), pointsy (i), pointsx (i + 1), pointsy (i + 1), black)
    end for
    %connect the last one to the first one
    drawline (pointsx (1), pointsy (1), pointsx (n), pointsy (n), black)
    %colours may be changed, this last line simply fills it with green
    drawfill (x, y, brightgreen, black)
end DrawNSidedShape
var win : int := Window.Open ("position:left;top")
loop
    var numSides : int
    get numSides
    exit when numSides = 0
    DrawNSidedShape (maxx div 2, maxy div 2, numSides, maxy div 2, 0)
    Input.Pause
    drawoval (maxx div 2, maxy div 2, maxy div 2, maxy div 2, black)
    Input.Pause
    cls
end loop
Window.Close (win)