type labelType :
    record
        name : string (20)
        link : int
    end record
const null := 0
const maxLabels := 100
var labels : array 1 .. maxLabels of labelType
var first := null
var vacant : int := 1
for i : 1 .. maxLabels - 1
    labels (i).link := i + 1
end for
procedure insert (newLabel : labelType)
    assert vacant not= null
    var spot := vacant
    vacant := labels (vacant).link
    labels (spot).name := newLabel.name
    if first = null or newLabel.name < labels (first).name then
        labels (spot).link := first
        first := spot
    else
        var previous := first
        var next := labels (first).link
        loop
            exit when next = null or
                newLabel.name < labels (next).name
            previous := next
            next := labels (next).link
        end loop
        labels (previous).link := spot
        labels (spot).link := next
    end if
end insert
procedure delete (oldLabel : labelType)
    var old : int := first
    var previous : int
    loop
        exit when old = null or labels (old).name = oldLabel.name
        previous := old
        old := labels (old).link
    end loop
    if old = null then
        put oldLabel.name, "not found"
        return
    elsif first = old then
        first := labels (old).link
    else
        labels (previous).link := labels (old).link
    end if
    labels (old).link := vacant
    vacant := old
end delete
procedure outputList
    var current := first
    loop
        exit when current = null
        put labels (current).name : 20
        current := labels (current).link
    end loop
end outputList
var newLabel, oldLabel : labelType
loop
    put "Enter name of label to be instered"
    get newLabel.name
    exit when (newLabel.name = 'fin') or (newLabel.name = 'Fin')
    insert (newLabel)
end loop
cls
outputList
loop
    put "Enter name of record to be deleted"
    get oldLabel.name
    exit when oldLabel.name = 'no'
    delete (oldLabel)
end loop
put "The remaining survivors are:"
outputList