var colourStep : int := 500 %Colour changing speed %1000
var numPoints := 4 %Number of points in shape %4

View.Set ("graphics:max,max,offscreenonly,nobuttonbar,title:Screen Saver")
Text.ColourBack (7)
cls
type Colour :
    record
        g, r, b : real
    end record
var c : array 1 .. 3 of Colour
c (1).r := 0
c (1).g := 0
c (1).b := 0
c (2).r := Rand.Real ()
c (2).g := Rand.Real ()
c (2).b := Rand.Real ()
c (3) := c (1)
var x, y, a : array 1 .. numPoints of real
for i : 1 .. numPoints
    x (i) := Rand.Int (0, maxx)
    y (i) := Rand.Int (0, maxy)
    a (i) := Rand.Int (0, 360)
end for
var ticker : int := 0
var timer := Time.Elapsed
loop
    c (3).r += (c (2).r - c (1).r) / colourStep
    c (3).g += (c (2).g - c (1).g) / colourStep
    c (3).b += (c (2).b - c (1).b) / colourStep
    ticker += 1
    if ticker = colourStep then
        ticker := 0
        c (1) := c (2)
        c (2).r := Rand.Real ()
        c (2).g := Rand.Real ()
        c (2).b := Rand.Real ()
    end if
    RGB.SetColour (255, c (3).r, c (3).g, c (3).b)
    for i : 1 .. numPoints
        x (i) += cosd (a (i)) * 1
        y (i) += sind (a (i)) * 1
        if x (i) > maxx then
            a (i) := Rand.Int (90, 270)
        elsif x (i) < 0 then
            a (i) := Rand.Int (-90, 90)
        end if
        if y (i) > maxy then
            a (i) := Rand.Int (180, 360)
        elsif y (i) < 0 then
            a (i) := Rand.Int (0, 180)
        end if
    end for
    for i : 1 .. numPoints
        Draw.ThickLine (round (x (i)), round (y (i)), round (x (i mod numPoints + 1)), round (y (i mod numPoints + 1)), 2, 255)
    end for
    exit when hasch
    if Time.Elapsed - timer >= 25 then
        timer := Time.Elapsed
        View.Update
    end if
    Time.DelaySinceLast(1)
end loop