%Matrix Screen, I guess (:

View.Set ("title:Matrix")
View.Set ("graphics:max,max,nobuttonbar") %good call on filling the screen (:
View.Set ("offscreenonly")

const TOTALAMT := 200 %# of trails total
const CLRAMT := 5 %# of trails per letter

const ARANGESTR := 33 %start of ascii range
const ARANGEEND := 122 %end of ascii range

const FONT := Font.New ("mono:24")

const OFFINT := 2 %rate of offset
const OFFMAX := 10 %max offset multiplier

const VRATEMIN := 5 %min speed
const VRATEMAX := 10 %maxspeed

%color stuff
const GREENADD := 80
const GREENSTART := RGB.maxcolor + 1
var GREENEND : int

type pnt :
    record
        x : int
        y : int
    end record

type mletter :
    record
        drk : int %darkness 1-CLRAMT
        ltr : string (1) %letter
        off : int %offset
        offmax : int %max offset
    end record

type mtext :
    record
        pos : pnt
        ltrs : array 1 .. CLRAMT of mletter
        rate : int
    end record

var ch : array char of boolean %chars for exit
var m : array 1 .. TOTALAMT of mtext %array of texts

fcn point (x, y : int) : pnt
    var t : pnt
    t.x := x
    t.y := y
    result t
end point

fcn gen_letter (off : int) : mletter
    var t : mletter
    t.drk := Rand.Int (GREENSTART, GREENSTART + ((GREENEND - GREENSTART) div 2))
    t.ltr := chr (Rand.Int (ARANGESTR, ARANGEEND))
    t.off := 0
    t.offmax := 2 * (OFFMAX * (off - 1))
    result t
end gen_letter

fcn gentext : mtext
    var t : mtext
    t.pos := point (Rand.Int (-50, maxx + 50), Rand.Int (maxy, maxy * 2))
    t.rate := Rand.Int (VRATEMIN, VRATEMAX)
    for i : 1 .. CLRAMT
        t.ltrs (i) := gen_letter (i)
    end for
    result t
end gentext

proc firstrun
    for i : 1 .. TOTALAMT
        m (i) := gentext
    end for
end firstrun

proc clampadd (var val : int, step, maxv : int)
    if (val + step < maxv) then
        val += step
    end if
end clampadd
proc clampsub (var val : int, step, minv : int)
    if (val - step > minv) then
        val -= step
    end if
end clampsub

proc mkgreenrange ()
    var i := 180
    var clr : int
    var gval := GREENADD + i
    loop
        if (i < 0) then
            i := 0
        else
            i -= 2
        end if
        gval -= 2
        exit when (gval < 0)
        clr := RGB.AddColor (i / 255, gval / 255, i / 255)
        exit when clr = 1
    end loop
    GREENEND := RGB.maxcolor
end mkgreenrange
mkgreenrange

proc updatemtext (k : int)
    m (k).pos.y -= m (k).rate
    for i : 1 .. CLRAMT
        clampadd (m (k).ltrs (i).drk, Rand.Int (0, 1), GREENEND)
        clampsub (m (k).ltrs (i).off, OFFINT, -m (k).ltrs (i).offmax)
    end for
    if (m (k).pos.y < -OFFMAX * CLRAMT) then
        m (k) := gentext
    end if
end updatemtext

proc drawmtext (k : int)
    for i : 1 .. CLRAMT
        Font.Draw (m (k).ltrs (i).ltr, m (k).pos.x, m (k).pos.y + m (k).ltrs (i).off, FONT, m (k).ltrs (i).drk)
    end for
end drawmtext

firstrun
loop

    drawfillbox (0, 0, maxx, maxy, black)
    for i : 1 .. TOTALAMT
        updatemtext (i)
        drawmtext (i)
    end for
    View.Update ()

    Time.DelaySinceLast (40)
    % Exit on spacebar
    Input.KeyDown (ch)
    exit when (ch (' '))
end loop

/* Matrix.t
 Matrixified
 Adrien Johnson
 Oct 22 */
View.Set ("screen:30;80,nobuttonbar,offscreenonly,title:Matrix,")

const minchar : int := 33
const maxchar : int := 255
/* which charaters to use. change if you want */
const newlines : int := 2
/* new lines created per step */
const greenshades : int := 30
/* higher the number, slower the fade */

type singleLetter :
    record
        justDropped : boolean
        symbol : char
        shade : int
    end record

var greens : array 0 .. greenshades of int
/* Stores colour numbers for shades of green */

var screen : array 1 .. maxrow, 1 .. maxcol of singleLetter
/* Stores the current state of the screen */

for i : 0 .. greenshades
    greens (i) := RGB.AddColour (0.0, i * 1 / greenshades, 0.0)
end for
/* initialises greens to the colour numbers of the shades, 0 is blackest, greenshades is greenest */

proc drawScreen
    for row : 1 .. maxrow
        for col : 1 .. maxcol
            locate (row, col)
            colour (greens (screen (row, col).shade))
            put screen (row, col).symbol ..
        end for
    end for
end drawScreen

proc initScreen
    for row : 1 .. maxrow
        for col : 1 .. maxcol
            screen (row, col).justDropped := false
            screen (row, col).symbol := chr (Rand.Int (minchar, maxchar))
            screen (row, col).shade := 0
        end for
    end for
end initScreen

proc fade
    for row : 1 .. maxrow
        for col : 1 .. maxcol
            if screen (row, col).shade > 0 then
                screen (row, col).shade -= 1
            end if
        end for
    end for
end fade

proc drop
    for decreasing row : maxrow .. 2
        for col : 1 .. maxcol
            if screen (row - 1, col).justDropped then
                screen (row, col).justDropped := true
                screen (row - 1, col).justDropped := false
                screen (row, col).shade := greenshades
            end if
        end for
    end for
end drop

proc clearbottom
    for col : 1 .. maxcol
        screen (maxrow, col).justDropped := false
    end for
end clearbottom

proc gentop
    for i : 1 .. newlines
        screen (1, Rand.Int (1, maxcol)).justDropped := true
        screen (1, Rand.Int (1, maxcol)).shade := greenshades
        screen (1, Rand.Int (1, maxcol)).symbol := chr (Rand.Int (minchar, maxchar))
    end for
end gentop

%%%%%%%%%%%%%%%%
% MAIN PROGRAM %
%%%%%%%%%%%%%%%%

initScreen
colourback (black)

loop
    Draw.Cls
    drawScreen
    View.Update
    clearbottom
    drop
    fade
    gentop
    delay (100)
end loop

View.Set ("screen:30;80,nobuttonbar,offscreenonly,title:Matrix,")

View.Set ("screen:max;max,nobuttonbar,offscreenonly,title:Matrix,")