class Resizer

    import Window
    export Initialize, Run

    var windowHeight, windowWidth : int2
    var windowX, windowY : int
    var width, height : nat1
    var resize : boolean := false

    procedure Initialize (width_, height_ : nat1)
        width := width_
        height := height_
        windowHeight := maxy
        windowWidth := maxx
    end Initialize

    procedure Run (mouseX, mouseY, mouseB : int2)

        Draw.FillBox (maxx - width, maxy - height, maxx, maxy, white)
        Draw.FillBox (maxx - width, maxy - height, maxx - (width div 5), maxy - (height div 5), black)
        Draw.FillBox (maxx - width, maxy - height, maxx - (width div 3), maxy - (height div 3), white)
        Draw.Box (maxx - width, maxy - height, maxx, maxy, black)

        if mouseX >= maxx - width and mouseX <= maxx and
                mouseY >= maxy - height and mouseY <= maxy and
                mouseB = 1 then
            resize := true
            Window.GetPosition (-1, windowX, windowY)
        end if

        if resize then
            windowWidth := mouseX + width div 2
            windowHeight := mouseY + height div 2
            Window.Set (Window.GetSelect, "graphics:" + intstr (windowWidth) + ";" + intstr (windowHeight) +
                ",position:" + intstr (windowX) + ";" + intstr (windowY))
            if mouseB = 0 then
                resize := false
            end if
        end if

    end Run
end Resizer

View.Set ("offscreenonly,position:center;center")

var mouseX, mouseY, mouseB : int
var sizor : ^Resizer

new sizor

sizor -> Initialize (20, 20)


loop
    Mouse.Where (mouseX, mouseY, mouseB)
    sizor -> Run (mouseX, mouseY, mouseB)

    View.Update
    Time.Delay (3)
    Draw.Cls
end loop