var ColorPicker : nat1 :=
    Window.Open ("offscreenonly,nobuttonbar,graphics:370;140,title:Color")
var font : int := Font.New ("arial:14")
var Red, Green, Blue : nat1 := 255
var mouseX, mouseY, mouseB : int
var buttonActive : boolean := false

function CalculateColor (startColor, endColor : int, ratio : real) : int

    var startRed, startGreen, startBlue, endRed, endGreen, endBlue : real

    RGB.GetColour (startColor, startRed, startGreen, startBlue)
    RGB.GetColour (endColor, endRed, endGreen, endBlue)

    var Red : real := startRed * ratio + endRed * (1 - ratio)
    var Green : real := startGreen * ratio + endGreen * (1 - ratio)
    var Blue : real := startBlue * ratio + endBlue * (1 - ratio)

    RGB.SetColor (110, Red, Green, Blue)
    result 110
end CalculateColor

procedure gradientBox (x1, y1, x2, y2, startColor, endColor : int)
    for i : x1 .. x2 - 1
        Draw.Line (i, y1, i, y2, CalculateColor (endColor, startColor,
            (i - x1) / abs (x2 - x1)))
    end for
end gradientBox


function scroll (mouseX, mouseY, mouseB, x, y,
        width, height, default, Color : int) : nat1

    gradientBox (x, y, x + width, y + height, 112, 111)
    Draw.Box (x, y, x + width, y + height, black)
    Draw.FillOval (default + x, y + height div 2, 3, 8, Color)
    Draw.Oval (default + x, y + height div 2, 3, 8, black)

    if mouseX > x and mouseX < x + width and mouseY > y and
            mouseY < y + height and mouseB = 1 then
        result mouseX - x
    end if

    result default
end scroll

loop
    Mouse.Where (mouseX, mouseY, mouseB)

    % Color Display
    Draw.FillBox (10, maxy - 100, 100, maxy - 10, 111)
    Draw.Box (10, maxy - 100, 100, maxy - 10, black)

    % Scrollbars
    RGB.SetColor (111, 0, Green, Blue)
    RGB.SetColor (112, 1, Green, Blue)
    Red := scroll (mouseX, mouseY, mouseB,
        110, 105, 255, 20, Red, brightred)
    RGB.SetColor (111, Red, 0, Blue)
    RGB.SetColor (112, Red, 1, Blue)
    Green := scroll (mouseX, mouseY, mouseB,
        110, 75, 255, 20, Green, brightgreen)
    RGB.SetColor (111, Red, Green, 0)
    RGB.SetColor (112, Red, Green, 1)
    Blue := scroll (mouseX, mouseY, mouseB,
        110, 45, 255, 20, Blue, brightblue)
    RGB.SetColor (111, Red, Green, Blue)
    %----------

    % OK button
    if buttonActive and mouseB = 0 then
        buttonActive := false
        exit
    end if
    RGB.SetColor (110, 0.95, 0.94, 0.91)
    if mouseX > 310 and mouseX < 368 and mouseY > 2 and mouseY < 28 then
        if mouseB = 1 then
            buttonActive := true
            RGB.SetColor (110, 0.87, 0.87, 0.81)
        else
            buttonActive := false
            RGB.SetColor (110, 0.95, 0.94, 0.84)
        end if
    end if
    Draw.FillBox (310, 2, 368, 28, 110)
    Draw.Box (310, 2, 368, 28, black)
    Draw.Box (310, 2 + 1, 368 - 1, 28, black)
    Draw.Text ("Ok", 327, 10, font, black)
    %------------

    View.Update
    delay (5)
    Draw.Cls
end loop

Window.Close (ColorPicker)