% made by fishtastic
% control: left and right arrow.
% have fun!

var map : array 1 .. maxrow, 1 .. maxcol of int
var col : array 1 .. 25 of int
var x := 40
var y := maxrow
var key : array char of boolean
var line := repeat (" ", 26)
var gameOver := false

loop
    put "Enter a Pointless Line. (25 characters or shorter)"
    put "The longer then line is, the harder the game is."
    put ""
    get line : *
    exit when length (line) <= 25
end loop

for i : 1 .. length (line)
    col (i) := RGB.AddColor (0, i * (0.69 / length (line)) + 0.3, 0)
end for

for i : 1 .. maxrow
    for j : 1 .. maxcol
        map (i, j) := 0
    end for
end for

View.Set ("offscreenonly")
colour (green)
colourback (black)

loop
    cls
    map (1, Rand.Int (1, maxcol)) := length (line)

    for decreasing i : maxrow .. 2
        for j : 1 .. maxcol
            map (i, j) := map (i - 1, j)
            map (i - 1, j) := map (i, j) - 1
        end for
    end for

    for i : 1 .. maxrow
        for j : 1 .. maxcol
            if map (i, j) > 0 then
                if 256 + length (line) - map (i, j) > maxcolor then
                    color (green)
                else
                    colour (256 + length (line) - map (i, j))
                end if
                put line (map (i, j)) ..
                if y = i and x = j then
                    gameOver := true
                end if
            else
                if i = y and j = x then
                    color (white)
                    put "@" ..
                else
                    put " " ..
                end if
            end if
        end for
    end for

    for i : 1 .. 25
        drawline (0, Rand.Int (0, maxy), maxx, Rand.Int (0, maxy), black)
    end for

    View.Update
    Input.KeyDown (key)
    if key (KEY_LEFT_ARROW) and x > 1 then
        x -= 1
    end if
    if key (KEY_RIGHT_ARROW) and x < 80 then
        x += 1
    end if

    exit when gameOver
end loop

put "GAME OVER"
View.Update