% some constants, tweak this to your liking
const GROUND_HEIGHT := 120
const RUN_SPEED := 10
const JUMP_SPEED := 30
const GRAVITY := 2
%four new constants controlling where your platform is
const BOX_x1 := 170
const BOX_y1 := 170
const BOX_x2 := 300
const BOX_y2 := 200
%end of my revisions
var win := Window.Open ("graphics:640;480,offscreenonly")
var chars : array char of boolean

% player position and velocity
var posx, posy : int
var velx, vely : real

posx := 20
velx := 0
posy := 400
vely := 0
loop
    Input.KeyDown (chars)
    if chars ('q') then
        exit
    end if

    % to make the player move
    if chars (KEY_LEFT_ARROW) then
        velx := -RUN_SPEED
    elsif chars (KEY_RIGHT_ARROW) then
        velx := RUN_SPEED
    else
        velx := 0
    end if

    % remember, in order to jump you MUST be on the ground when pressing UP
    if chars (KEY_UP_ARROW) and posy = GROUND_HEIGHT then
        vely := JUMP_SPEED
    end if
    %again follow the ubove if statement if the movable box is on the ground then so make it the platform to allow jumping from platform
    if chars (KEY_UP_ARROW) and posy = BOX_y2 and posx > BOX_x1 and posx < BOX_x2 then
        vely := JUMP_SPEED
    end if
    %end of my revisions
    % subtract your "gravity" constant from the velocity EACH frame
    vely -= GRAVITY
    posx += round (velx)
    posy += round (vely)

    % simple "collision" check. just makes sure the player stays above ground
    if posy < GROUND_HEIGHT then
        posy := GROUND_HEIGHT
        vely := 0
    end if
    %so if movable box isn't on the ground and he is in between box then set his y position to the height of the platform
    if posy not= GROUND_HEIGHT and posy < BOX_y2 and posx + 10 > BOX_x1 and posx < BOX_x2 then
        posy := BOX_y2
        vely := 0
    end if
    %end of my revisions
    % different colours just to illustrate whether or not you may jump
    if posy = GROUND_HEIGHT then
        drawfillbox (posx - 10, posy, posx + 10, posy + 20, green)
        %or he is on the platform change colours
    elsif posy = BOX_y2 then
        drawfillbox (posx - 10, posy, posx + 10, posy + 20, green)
        %end of my revisions
    else
        drawfillbox (posx - 10, posy, posx + 10, posy + 20, red)
    end if
    %draw the platform
    drawfillbox (BOX_x1, BOX_y1, BOX_x2, BOX_y2, 5)
    %end of my revisions
    drawline (0, GROUND_HEIGHT, maxx, GROUND_HEIGHT, blue)
    View.Update
    delay (25)
    cls
end loop