var netAddressB, netURL, netURL2, netDomain, data : string
var netStreamB, netStreamS, domainLength : int
var containSlash : boolean

loop
    put "Your IP is: ", Net.LocalAddress
    put "to use this proxy, go to:"
    put "http://", Net.LocalAddress, "/destination"
    put "Waiting for Browser Connection"
    put ""
    netStreamB := Net.WaitForConnection (80, netAddressB) % wait for connection from browser

    if netStreamB > 0 then % netSteam is only > 0 when connected
        put "Connected to browser at: ", netAddressB
        loop
            exit when Net.TokenAvailable (netStreamB) % this loop waits for data
        end loop

        get : netStreamB, data : 5 % takes away "get /"
        get : netStreamB, netURL % takes in the URL

        netDomain := "" % clears register
        domainLength := 1 % resets register
        containSlash := false

        if index (netURL, "/") > 0 then
            containSlash := true
            loop % this extracts domain of server
                if netURL (domainLength) not= "/" then
                    netDomain := netDomain + netURL (domainLength)
                    domainLength += 1
                else
                    exit
                end if
            end loop
        else
            netDomain := netURL
        end if

        netURL2 := ""

        for i : domainLength .. length (netURL)
            netURL2 := netURL2 + netURL (i) % take out domain name from request
        end for

        loop % this is an inefficient patch to add the slash if one is missing at the beginning
            if containSlash then
                for i : domainLength .. length (netURL)
                    if netURL (i) not= "/" and i = domainLength then
                        netURL2 := netURL2 + netURL (i)
                    end if
                end for
            else
                netURL2 := "/"
            end if
            if length (netURL2) > 0 then
                if netURL2 (1) not= "/" then
                    netURL2 := "/"
                else
                    exit
                end if
            else
                netURL2 := "/"
            end if
        end loop

        netURL := netURL2

        put "Domain: ", netDomain
        put "URL: http://", netDomain, netURL
        netDomain := Net.HostAddressFromName (netDomain)
        netStreamS := Net.OpenConnection (netDomain, 80) % connect to server

        if netStreamS > 0 then % only if connected

            put : netStreamS, "GET " + netURL + " " % send request to server

            loop % relay the rest of the data from the browser to the server
                get : netStreamB, data : 1
                put : netStreamS, data ..
                %put data ..
                exit when ~Net.TokenAvailable (netStreamB) % when browser finishes sending, this loop exits
            end loop

            loop
                exit when Net.TokenAvailable (netStreamS) % wait for response from server
            end loop

            loop % relay data from server to browser
                get : netStreamS, data
                put : netStreamB, " " ..
                put : netStreamB, data ..
                %put data ..
                exit when ~Net.TokenAvailable (netStreamS) % wait for server to finish
            end loop

            close : netStreamS % close connection
            put "Server Connection Closed"
        else
            put "Server Connection Failed"
            delay (1000)
        end if
        close : netStreamB % close connection
        put "Browser Connection Closed"
    else
        put "Browser Connection Failed"
        delay (1000)
    end if
    put "Finished Request"
    put ""
end loop