Computer Science Canada :: View topic - Two dimential array map grid????

setscreen ("offscreenonly,graphics:300;300")
/*
the tiles are going to be 10x10 pixels
and since there are 300 pixels on the x coordinate we can have 30 blocks on it
similarly since there are 300 pixels on the y coordinate we can have 30 bloacks on it
in total we have 90 blocks because 30x30=90
*/
var tile : array 0 .. 29, 0 .. 29 of int

%the variable for the player x,y is the real position cx,cy is the position on our grid
var player :
record
x, y, cx, cy : int
end record

%for input.keydown
var key : array char of boolean

%to get the tile types
var fileName : string := "map.txt"
var fileNo : int := 0

%gets the tile types in the data file
open : fileNo, fileName, get
for decreasing y : 29 .. 0
for x : 0 .. 29
get : fileNo, tile (x, y)
end for
end for
close : fileNo

%draws the map
proc redraw
for y : 0 .. 29
for x : 0 .. 29
if tile (x, y) = 0 then
% this draws an open square
%the rest draw closed squares of different colours
drawfillbox (10 * x, y * 10, 10 + 10 * x, y * 10 + 10, black)
elsif tile (x, y) = 1 then
drawfillbox (10 * x, y * 10, 10 + 10 * x, y * 10 + 10, red)
elsif tile (x, y) = 2 then
drawfillbox (10 * x, y * 10, 10 + 10 * x, y * 10 + 10, blue)
elsif tile (x, y) = 3 then
drawfillbox (10 * x, y * 10, 10 + 10 * x, y * 10 + 10, green)
end if

end for

end for
end redraw

%determins weather the square you are going to be in is open or not
function collide (x, y : int) : boolean
result tile (x, y) = 0
end collide

player.x := 0
player.y := 0

%cx and cy keeps track of where you are in terms of our grid and x,y keeps track of where you are on the screen
player.cx := 0
player.cy := 0

%puts everything together
loop
Input.KeyDown (key)
redraw
if key ('w') and collide (player.cx, player.cy + 1) then
player.y += 10
player.cy += 1 %moved up 1 y unit in our grid
end if
if key ('s') and collide (player.cx, player.cy - 1) then
player.y -= 10
player.cy -= 1 %moved down 1 y unit in our grid
end if
if key ('d') and collide (player.cx + 1, player.cy) then
player.x += 10
player.cx += 1 %moved up 1 x unit in our grid
end if
if key ('a') and collide (player.cx - 1, player.cy) then
player.x -= 10
player.cx -= 1 %moved down 1 x unit in our grid
end if
drawfillbox (player.x, player.y, player.x + 10, player.y + 10, yellow)
View.Update
Time.DelaySinceLast (50)
end loop

Author:	BenLi [ Wed Feb 28, 2007 5:03 pm ]
Post subject:	RE:Two dimential array map grid????
okay, you need to understand one dimensional before you venture into multi dimensional arrays. So basically, an array is a mass of variables that are know by one name but referenced by numbers. I suggest doing the questions that the tutorial suggests you complete to acquaint yourself with the concept

Author:	kirstenpratt [ Wed Feb 28, 2007 9:27 pm ]
Post subject:	Re: Two dimential array map grid????
ok thankyou your code is awesome but how can i fit that in with my pacman?i dont get it if you could can u help thank you so much

Author:	CodeMonkey2000 [ Wed Feb 28, 2007 10:33 pm ]
Post subject:	Re: Two dimential array map grid????
What part don't you understand? If it is about 2d arrays there is a tutorial about it here (just scroll further down in the thread, it is a few posts down)http://www.compsci.ca/v3/viewtopic.php?t=14333. If it is about file input/output there is a tutorial herehttp://www.compsci.ca/v3/viewtopic.php?t=12972