% variables
%%% important part %%%
var framespersecond : int := 20 % change me, this is the desired frames per second
var framesdelay : int := 1000 div framespersecond
var timer1, timer2, timer3, fps : int := 0
%%% / important part %%%

var numofdots : int := 10
var upordown : int := 1

var xpos : int := 0

setscreen ("offscreenonly") % flicker free

% main loop
loop
    % draws some random dots
    for i : 1 .. numofdots
        Draw.Dot (Rand.Int (1, 300), Rand.Int (1, 300), Rand.Int (1, 100))
    end for
    if upordown = 1 then
        numofdots += 60
    elsif upordown = 2 then
        numofdots -= 60
    end if
    if numofdots > 20000 or fps < 6 then
        upordown := 2
    elsif numofdots < 70 then
        upordown := 1
    end if
    Draw.FillOval (xpos, 150, 20, 20, brightred)
    xpos += 10
    if xpos > 300 then
        xpos := 0
    end if
    %%% important part %%%
    % finds actual frames per second
    timer2 := timer1
    timer1 := Time.Elapsed
    timer3 := timer1 - timer2
    fps := 1000 div timer3
    % calculates lag and adjust rate accordingly
    if fps > framespersecond then
        framesdelay += 2
    elsif fps < framespersecond and framesdelay > - 10 then
        framesdelay -= 2
    end if
    Text.Locate (1, 1)
    put "number of dots: ", numofdots
    put "current frames per second: ", fps
    put "current frame delay (in ms): ", framesdelay
    if framesdelay < 1 then
        put "LAG!!!"
    end if
    if upordown = 1 then
        put "slower..."
    else
        put "faster..."
    end if
    delay (framesdelay) % delay
    View.Update % displays all graphics
    cls % clears the screen
    %%% / important part %%%
end loop

fcn Distance (x, y, x2, y2 : int) : real
    result sqrt ((x2 - x ** 2 +  (y2 - y) ** 2))
end Distance