fcn textFilter (key : char) : boolean
    result key < ' ' or key > '~'
end textFilter

class Getter
    import Input, textFilter
    export addFilter, getString, move, start, activate, deactivate, setFont,
        setColour, update

    var done : boolean
    var x, y : int
    var chars : flexible array 0 .. -1 of char
    var bound : int
    var font : int := defFontID
    var clr : int := black
    var active : boolean
    var text : string

    type filterFunction : fcn filter (key : char) : boolean
    var filters : flexible array 0 .. -1 of filterFunction
    var filterBound : int := 0
    new filters, filterBound
    filters (0) := textFilter

    fcn getString () : string
        result text
    end getString

    proc addFilter (newFilter : filterFunction)
        filterBound += 1
        new filters, filterBound
        filters (filterBound) := newFilter
    end addFilter

    proc makeText ()
        text := ""
        for i : 0 .. bound
            text += chars (i)
        end for
    end makeText

    proc move (newX, newY : int)
        x := newX
        y := newY
    end move

    proc start (x, y : int)
        move (x, y)
        done := false
        bound := -1
        active := true
        text := ""
    end start

    proc activate ()
        active := true
    end activate

    proc deactivate ()
        active := false
    end deactivate

    proc setFont (fontID : int)
        font := fontID
    end setFont

    proc setColour (newColour : int)
        clr := newColour
    end setColour

    fcn filtered (key : char) : boolean
        for i : 0 .. filterBound
            if filters (i) (key) then
                result true
            end if
        end for
        result false
    end filtered

    proc parseKey (key : char)
        if key = KEY_ENTER then
            done := true

        elsif key = KEY_BACKSPACE then
            if bound > -1 then
                bound -= 1
            end if

        elsif not filtered (key) then
            bound += 1
            new chars, bound
            chars (bound) := key
        end if

        makeText ()
    end parseKey

    proc display ()
        Font.Draw (text, x, y, defFontID, clr)
    end display

    fcn update () : boolean
        if not done and active then
            if Input.hasch () then
                parseKey (Input.getchar ())
            end if
        end if
        display ()
        result not done
    end update
end Getter

var getter : ^Getter
new Getter, getter
getter -> start (100, 100)
loop
    exit when not getter -> update ()
    delay (10)
    cls
end loop
put getter -> getString ()

fcn numFilter (key : char) : boolean
    result key >= '0' and key <= '9'
end numFilter

var getter : ^Getter
new Getter, getter
getter -> start (100, 100)
getter -> addFilter (numFilter)
getter -> setFont (Font.New ("Arial:20"))
getter -> setColour (blue)
loop
    exit when not getter -> update ()
    delay (10)
    cls
end loop
put getter -> getString ()

import Getter