setscreen ("offscreenonly")
class Ball
    export draw, move, set_move, set_position

    var size : int := 10
    var x, y : int := Rand.Int (200, 400)
    var vx, vy : int
    var speed : int
    var c : int := 7

    proc set_move
        vx := Rand.Int (-5, 5)
        vy := Rand.Int (-5, 5)
    end set_move

    proc set_position (xpos, ypos : int)
        x := xpos
        y := ypos
    end set_position

    proc move
        x += vx
        y += vy

        if x >= maxx then
            x := 0 - size
        elsif x + size <= 0 then
            x := maxx
        end if
        if y >= maxy then
            y := 0 - size
        elsif y + size <= 0 then
            y := maxy
        end if
    end move

    proc draw
        Draw.FillOval (x, y, size, size, c)
    end draw

end Ball


var balls : flexible array 1 .. 1 of ^Ball
new balls (1)
balls (1) -> set_move

var mx, my, mb : int

var keys: array char of boolean

proc assign_new_balls
    new balls (upper (balls))
    balls (upper (balls)) -> set_position (mx, my)
    balls (upper (balls)) -> set_move
end assign_new_balls

loop
    Input.KeyDown(keys)
    Mouse.Where (mx, my, mb)
    if mb = 1 then
        new balls, upper (balls) + 1
        assign_new_balls
    end if

    if keys (KEY_ENTER) then
        new balls, 1
        assign_new_balls
    end if

    cls
    for i : 1 .. upper (balls)
        balls (i) -> move
        balls (i) -> draw
    end for
    View.Update
    delay (20)
end loop