const maxdepth := 50 %Change this if you plan on zooming in farther than, say, 3 medium zooms.  The picture will become clearer,
%but take longer to load.
var left : real := -2
var right : real := 2
var bottom : real := -2
var top : real := 2

type CoOrd :
    record
        a, b : real
    end record

function SquareIt (z : CoOrd) : CoOrd
    var z2 : CoOrd

    z2.a := 2 * z.a * z.b
    z2.b := z.b ** 2 - z.a ** 2
    result z2
end SquareIt

function AddIt (z, z3 : CoOrd) : CoOrd
    var z2 : CoOrd
    z2.a := z.a + z3.a
    z2.b := z.b + z3.b
    result z2
end AddIt

function FindColour (z : CoOrd) : int
    var z2 : CoOrd := z
    for i : 0 .. maxdepth
        z2 := SquareIt (z2)
        z2 := AddIt (z2, z)
        if sqrt (z2.a ** 2 + z2.b ** 2) > 2 then
            result i
        end if
    end for
    result maxdepth
end FindColour

var z : CoOrd
var mx, my, button : int
var mandlepic : int
var newleft, newright, newtop, newbottom : real
loop
    View.Set ('nooffscreenonly')
    for j : 0 .. maxy
        for i : 0 .. maxx
            z.a := (top - bottom) * j / maxy + bottom
            z.b := (right - left) * i / maxx + left
            drawdot (i, j, round (FindColour (z) / maxdepth * 254) + 1)
        end for
    end for
    View.Set ('offscreenonly')
    mandlepic := Pic.New (0, 0, maxx, maxy)
    loop
        mousewhere (mx, my, button)
        if button = 1 then
            newleft := mx
            newbottom := my
            loop
                mousewhere (mx, my, button)
                Pic.Draw (mandlepic, 0, 0, picCopy)
                drawbox (round (newleft), round (newbottom), mx, my, brightblue)
                View.Update
                cls
                exit when button = 0
            end loop
            exit when mx > newleft and my > newbottom
        end if
    end loop
    Pic.Free (mandlepic)
    newtop := (top - bottom) * my / maxy + bottom
    newbottom := (top - bottom) * newbottom / maxy + bottom

    newright := (right - left) * mx / maxx + left
    newleft := (right - left) * newleft / maxx + left

    left := newleft
    right := newright
    bottom := newbottom
    top := newtop
end loop