You should rewrite as many of those procedures as possible as functions.
But even if you keep the procedures, you should make sure that you don't have any reliance on global variables.
Consider something like a program where you want to move something around the screen, and you're keeping track of x and y coordinates. You might have a procedure to move them diagonally, where each coordinate gets increased by 1.
| code: | var x, y : int := 0
procedure moveDiagonally
x += 1
y += 1
end moveDiagonally
moveDiagonally |
Instead of relying on those variables existing, let's pass in any two variables.
| code: | procedure moveDiagonally(var x, y : int)
x += 1
y += 1
end moveDiagonally
var x, y : int := 0
moveDiagonally(x, y) |
The other major improvement you can make is to learn to use records to tie related pieces of information together.
Instead of passing in the x and y coordinates separately, we create a record which holds both of them and lets us treat the two integers together as a single piece of data.
| code: | type Point : record
x : int
y : int
end record
procedure moveDiagonally(var p : Point)
p.x += 1
p.y += 1
end moveDiagonally
var p : Point
moveDiagonally(p) |
Of course, we can improve on even that, by incorporating classes, where we hide the actual data, and only allow very select access to it. This prevents unintended data corruption.
| code: | class Point
export init, getX, getY, moveDiagonally
var x, y : int
procedure init(init_x, init_y : int)
x := init_x
y := init_y
end init
function getX : int
result x
end getX
function getY : int
result y
end getY
procedure moveDiagonally
x += 1
y += 1
end moveDiagonally
end Point
var p : pointer to Point
new Point, p
p->init(0, 0)
p->moveDiagonally |
|
that is a good question, cuz i copied that last bit of wtd's code and it made 